Gestion des répertoires avec pwd, cd et ls
publication: 21 novembre 2026 / mis à jour 21 novembre 2026
Quand on utilise eForth Windows, il est fréquent de vouloir charger des fichiers installés dans d'autres dossiers. Pour éviter de se perdre, il devient nécessaire de donner accès à ces dossiers et sous-dossiers.
Affichage du répertoire courant avec pwd
Le mot pwd que l'on va définir est hérité du monde Linux: PWD pour Print Working Directory.
Voici sa définition:
260 constant MAX_PATH
create cwd-buf
MAX_PATH 1+ allot
\ récupère le chemin courant
z" GetCurrentDirectoryA" 2 Kernel32 GetCurrentDirectoryA ( n buf -- len )
: getcwd ( -- a n )
MAX_PATH cwd-buf GetCurrentDirectoryA cwd-buf swap
;
\ display current directory
\ pwd = print working directory
: pwd ( -- )
getcwd type cr ;
L'exécution du mot pwd affiche le répertoire courant dans lequel on travaille. Ce mot
n'a besoin d'aucun paramètre. Son usage se limitera au mode interprété pour connaitre le dossier courant
dans lequel eForth opère. Exemple:
--> pwd \ affiche: C:\Users\mpmp9\OneDrive\Bureau\eforth\MUSICS\tests
Sélection du répertoire courant avec cd
Le mot cd est également hérité du monte Linux, mais a son équivalent Windows.
Voici sa définition:
z" SetCurrentDirectoryA" 1 Kernel32 SetCurrentDirectoryA ( z -- fl ) \ select other directory, use in compilation : (cd) ( zPath -- ) SetCurrentDirectoryA drop ; \ select other directory, use in iterpret only : cd ( --) state @ if abort" cd : Interpret only!" then bl parse s>z (cd) ; immediate
Ici, nous avons défini deux versions:
(cd)qui est utilisable dans le corps d'une définition, précédé d'une chaîne de type zStr qui débute par le motz"cdqui n'est utilisable qu'en mode interprété et suivi du dossier à sélectionner
Exemple d'utilisation de cd en mode interprété:
--> pwd C:\Users\mpmp9\OneDrive\Bureau\eforth ok --> cd MUSICS ok --> pwd C:\Users\mpmp9\OneDrive\Bureau\eforth\MUSICS
Si on avait voulu sélectionner le répertoire MUSICS dans le corps d'une définition:
: cdMusicsDir ( -- )
z" MUSICS" (cd) ;
Liste des fichiers avec ls
Le mot ls est hérité du monde Linux. Son équivalent DOS/Windows est dir.
Le codage en FORTH de ls est un peu plus complexe. Voici sa définition:
z" FindFirstFileA" 2 Kernel32 FindFirstFileA ( z *fd -- hFind ) z" FindNextFileA" 2 Kernel32 FindNextFileA ( hFind *fd -- fl ) z" FindClose" 1 Kernel32 FindClose ( hFind -- fl ) create _fd 320 allot \ structure WIN32_FIND_DATAA variable hFind \ Accès aux champs de la structure : fd-attr ( -- n ) _fd UL@ ; \ attributs, offset 0 : fd-size ( -- n ) _fd 32 + UL@ ; \ taille (32 bits de poids faible), offset 32 : fd-name ( -- a n ) _fd 44 + z>s ; \ nom, offset 44 : fd-dir? ( -- f ) fd-attr $10 and 0<> ; \ FILE_ATTRIBUTE_DIRECTORY : .entry ( -- ) fd-dir? if ." <DIR> " else fd-size u. then fd-name type cr ; \ display files in path. path optionnal \ ls = abbreviated list : ls ( --) state @ if abort" ls : Interpret only!" then bl parse dup 0= if 2drop s" *" then s>z _fd FindFirstFileA dup hFind ! -1 = if ." not found" cr exit then begin .entry hFind @ _fd FindNextFileA 0= until hFind @ FindClose drop ; immediate
Les paramètres de ls sont passé après le mot ls.
Le mot ls n'est utilisable qu'en mode interprété.
ls sans paramètre équivaut à ls *
--> ls <DIR> . <DIR> .. 505 01_hello.fs 1512 02_test_PlaySoundA.fs 698 03_test_SetVolume.fs 200 04_test_cockrow.fs 403614 cockcrow.wav 1214 _fileTests.fs
L'exécution de ls avec un paramètre réduit la liste selon le masque spécifié. Ici on ne liste que les
fichiers avec l'extension wav:
--> ls *.wav 403614 cockcrow.wav
Si on passe un sous-dossier comme paramètre, il n'est plus nécessaire de se contraindre à utiliser le caractère \ :
--> ls .. <DIR> MUSICS ok --> ls ../.. <DIR> eforth ok --> ls ..\.. <DIR> eforth
Conclusion
Avec ces trois nouveaux mots pwd cd et ls, eForth Windows gagne en souplesse. Vous retrouverez le code
de ces mots ici:
Kernel extensions
Si vous respectez localement la structure des fichiers de ce dépôt sur votre espace de travail, vous pourrez intégrer le contenu de Kernel32-definitions.fs de cette manière::
\ stop compilation before end of included file : <EOF> ( -- ) #tib @ >in ! ; \ load windows extensions needs tools/dumpTool.fs \ load Winmm extensions needs extensions/Kernel32-definitions.fs
Legal: site web personnel sans commerce / personal site without seling
